diff -r 3fa21fbf9be7 -r a33cf9e2d7d8 common/autoconf/toolchain_windows.m4
--- a/common/autoconf/toolchain_windows.m4	Wed Jul 05 18:43:09 2017 +0200
+++ b/common/autoconf/toolchain_windows.m4	Wed Mar 06 10:50:37 2013 +0100
@@ -262,3 +262,59 @@
   AC_MSG_RESULT([$MSVCR_DLL])
   BASIC_FIXUP_PATH(MSVCR_DLL)
 ])
+
+
+# Setup the DXSDK paths
+AC_DEFUN([TOOLCHAIN_SETUP_DXSDK],
+[
+  AC_ARG_WITH(dxsdk, [AS_HELP_STRING([--with-dxsdk],
+      [the DirectX SDK (Windows only) @<:@probed@:>@])])
+  AC_ARG_WITH(dxsdk-lib, [AS_HELP_STRING([--with-dxsdk-lib],
+      [the DirectX SDK lib directory (Windows only) @<:@probed@:>@])])
+  AC_ARG_WITH(dxsdk-include, [AS_HELP_STRING([--with-dxsdk-include],
+      [the DirectX SDK include directory (Windows only) @<:@probed@:>@])])
+
+  AC_MSG_CHECKING([for DirectX SDK])
+
+  if test "x$with_dxsdk" != x; then
+    dxsdk_path="$with_dxsdk"
+  elif test "x$DXSDK_DIR" != x; then
+    dxsdk_path="$DXSDK_DIR"
+  else
+    AC_MSG_ERROR([Could not find the DirectX SDK])
+  fi
+  AC_MSG_RESULT([$dxsdk_path])
+  BASIC_FIXUP_PATH(dxsdk_path)
+
+  AC_MSG_CHECKING([for DirectX SDK lib dir])
+  if test "x$with_dxsdk_lib" != x; then
+    DXSDK_LIB_PATH="$with_dxsdk_lib"
+  elif test "x$OPENJDK_TARGET_CPU" = "xx86_64"; then
+    DXSDK_LIB_PATH="$dxsdk_path/Lib/x64"
+  else
+    DXSDK_LIB_PATH="$dxsdk_path/Lib"
+  fi
+  # dsound.lib is linked to in jsoundds
+  if test ! -f "$DXSDK_LIB_PATH/dsound.lib"; then
+    AC_MSG_ERROR([Invalid DirectX SDK lib dir])
+  fi
+  AC_MSG_RESULT([$DXSDK_LIB_PATH])
+  BASIC_FIXUP_PATH(DXSDK_LIB_PATH)
+
+  AC_MSG_CHECKING([for DirectX SDK include dir])
+  if test "x$with_dxsdk_include" != x; then
+    DXSDK_INCLUDE_PATH="$with_dxsdk_include"
+  else
+    DXSDK_INCLUDE_PATH="$dxsdk_path/Include"
+  fi
+  # dsound.h is included in jsoundds
+  if test ! -f "$DXSDK_INCLUDE_PATH/dsound.h"; then
+    AC_MSG_ERROR([Invalid DirectX SDK lib dir])
+  fi
+  AC_MSG_RESULT([$DXSDK_INCLUDE_PATH])
+  BASIC_FIXUP_PATH(DXSDK_INCLUDE_PATH)
+
+  AC_SUBST(DXSDK_LIB_PATH)
+  AC_SUBST(DXSDK_INCLUDE_PATH)
+  LDFLAGS_JDK="$LDFLAGS_JDK -libpath:$DXSDK_LIB_PATH"
+])