1 #

     2 # Copyright (c) 2011, 2017, Oracle and/or its affiliates. All rights reserved.

     3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.

     4 #

     5 # This code is free software; you can redistribute it and/or modify it

     6 # under the terms of the GNU General Public License version 2 only, as

     7 # published by the Free Software Foundation.  Oracle designates this

     8 # particular file as subject to the "Classpath" exception as provided

     9 # by Oracle in the LICENSE file that accompanied this code.

    10 #

    11 # This code is distributed in the hope that it will be useful, but WITHOUT

    12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or

    13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License

    14 # version 2 for more details (a copy is included in the LICENSE file that

    15 # accompanied this code).

    16 #

    17 # You should have received a copy of the GNU General Public License version

    18 # 2 along with this work; if not, write to the Free Software Foundation,

    19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.

    20 #

    21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA

    22 # or visit www.oracle.com if you need additional information or have any

    23 # questions.

    24 #

    25 

    26 # Create a function/macro that takes a series of named arguments. The call is

    27 # similar to AC_DEFUN, but the setup of the function looks like this:

    28 # BASIC_DEFUN_NAMED([MYFUNC], [FOO *BAR], [$@], [

    29 # ... do something

    30 #   AC_MSG_NOTICE([Value of BAR is ARG_BAR])

    31 # ])

    32 # A star (*) in front of a named argument means that it is required and it's

    33 # presence will be verified. To pass e.g. the first value as a normal indexed

    34 # argument, use [m4_shift($@)] as the third argument instead of [$@]. These

    35 # arguments are referenced in the function by their name prefixed by ARG_, e.g.

    36 # "ARG_FOO".

    37 #

    38 # The generated function can be called like this:

    39 # MYFUNC(FOO: [foo-val],

    40 #     BAR: [

    41 #         $ECHO hello world

    42 #     ])

    43 # Note that the argument value must start on the same line as the argument name.

    44 #

    45 # Argument 1: Name of the function to define

    46 # Argument 2: List of legal named arguments, with a * prefix for required arguments

    47 # Argument 3: Argument array to treat as named, typically $@

    48 # Argument 4: The main function body

    49 AC_DEFUN([BASIC_DEFUN_NAMED],

    50 [

    51   AC_DEFUN($1, [

    52     m4_foreach(arg, m4_split($2), [

    53       m4_if(m4_bregexp(arg, [^\*]), -1,

    54         [

    55           m4_set_add(legal_named_args, arg)

    56         ],

    57         [

    58           m4_set_add(legal_named_args, m4_substr(arg, 1))

    59           m4_set_add(required_named_args, m4_substr(arg, 1))

    60         ]

    61       )

    62     ])

    63 

    64     m4_foreach([arg], [$3], [

    65       m4_define(arg_name, m4_substr(arg, 0, m4_bregexp(arg, [: ])))

    66       m4_set_contains(legal_named_args, arg_name, [],[AC_MSG_ERROR([Internal error: arg_name is not a valid named argument to [$1]. Valid arguments are 'm4_set_contents(legal_named_args, [ ])'.])])

    67       m4_set_remove(required_named_args, arg_name)

    68       m4_set_remove(legal_named_args, arg_name)

    69       m4_pushdef([ARG_][]arg_name, m4_substr(arg, m4_incr(m4_incr(m4_bregexp(arg, [: ])))))

    70       m4_set_add(defined_args, arg_name)

    71       m4_undefine([arg_name])

    72     ])

    73     m4_set_empty(required_named_args, [], [

    74       AC_MSG_ERROR([Internal error: Required named arguments are missing for [$1]. Missing arguments: 'm4_set_contents(required_named_args, [ ])'])

    75     ])

    76     m4_foreach([arg], m4_indir([m4_dquote]m4_set_listc([legal_named_args])), [

    77       m4_pushdef([ARG_][]arg, [])

    78       m4_set_add(defined_args, arg)

    79     ])

    80     m4_set_delete(legal_named_args)

    81     m4_set_delete(required_named_args)

    82 

    83     # Execute function body

    84     $4

    85 

    86     m4_foreach([arg], m4_indir([m4_dquote]m4_set_listc([defined_args])), [

    87       m4_popdef([ARG_][]arg)

    88     ])

    89 

    90     m4_set_delete(defined_args)

    91   ])

    92 ])

    93 

    94 # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)

    95 # If so, then append $1 to $2 \

    96 # Also set JVM_ARG_OK to true/false depending on outcome.

    97 AC_DEFUN([ADD_JVM_ARG_IF_OK],

    98 [

    99   $ECHO "Check if jvm arg is ok: $1" >&AS_MESSAGE_LOG_FD

   100   $ECHO "Command: $3 $1 -version" >&AS_MESSAGE_LOG_FD

   101   OUTPUT=`$3 $1 -version 2>&1`

   102   FOUND_WARN=`$ECHO "$OUTPUT" | $GREP -i warn`

   103   FOUND_VERSION=`$ECHO $OUTPUT | $GREP " version \""`

   104   if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then

   105     $2="[$]$2 $1"

   106     JVM_ARG_OK=true

   107   else

   108     $ECHO "Arg failed:" >&AS_MESSAGE_LOG_FD

   109     $ECHO "$OUTPUT" >&AS_MESSAGE_LOG_FD

   110     JVM_ARG_OK=false

   111   fi

   112 ])

   113 

   114 # Appends a string to a path variable, only adding the : when needed.

   115 AC_DEFUN([BASIC_APPEND_TO_PATH],

   116 [

   117   if test "x$2" != x; then

   118     if test "x[$]$1" = x; then

   119       $1="$2"

   120     else

   121       $1="[$]$1:$2"

   122     fi

   123   fi

   124 ])

   125 

   126 # Prepends a string to a path variable, only adding the : when needed.

   127 AC_DEFUN([BASIC_PREPEND_TO_PATH],

   128 [

   129   if test "x$2" != x; then

   130     if test "x[$]$1" = x; then

   131       $1="$2"

   132     else

   133       $1="$2:[$]$1"

   134     fi

   135   fi

   136 ])

   137 

   138 # This will make sure the given variable points to a full and proper

   139 # path. This means:

   140 # 1) There will be no spaces in the path. On unix platforms,

   141 #    spaces in the path will result in an error. On Windows,

   142 #    the path will be rewritten using short-style to be space-free.

   143 # 2) The path will be absolute, and it will be in unix-style (on

   144 #     cygwin).

   145 # $1: The name of the variable to fix

   146 AC_DEFUN([BASIC_FIXUP_PATH],

   147 [

   148   # Only process if variable expands to non-empty

   149 

   150   if test "x[$]$1" != x; then

   151     if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then

   152       BASIC_FIXUP_PATH_CYGWIN($1)

   153     elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then

   154       BASIC_FIXUP_PATH_MSYS($1)

   155     else

   156       # We're on a unix platform. Hooray! :)

   157       path="[$]$1"

   158       has_space=`$ECHO "$path" | $GREP " "`

   159       if test "x$has_space" != x; then

   160         AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])

   161         AC_MSG_ERROR([Spaces are not allowed in this path.])

   162       fi

   163 

   164       # Use eval to expand a potential ~

   165       eval path="$path"

   166       if test ! -f "$path" && test ! -d "$path"; then

   167         AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])

   168       fi

   169 

   170       if test -d "$path"; then

   171         $1="`cd "$path"; $THEPWDCMD -L`"

   172       else

   173         dir="`$DIRNAME "$path"`"

   174         base="`$BASENAME "$path"`"

   175         $1="`cd "$dir"; $THEPWDCMD -L`/$base"

   176       fi

   177     fi

   178   fi

   179 ])

   180 

   181 # This will make sure the given variable points to a executable

   182 # with a full and proper path. This means:

   183 # 1) There will be no spaces in the path. On unix platforms,

   184 #    spaces in the path will result in an error. On Windows,

   185 #    the path will be rewritten using short-style to be space-free.

   186 # 2) The path will be absolute, and it will be in unix-style (on

   187 #     cygwin).

   188 # Any arguments given to the executable is preserved.

   189 # If the input variable does not have a directory specification, then

   190 # it need to be in the PATH.

   191 # $1: The name of the variable to fix

   192 AC_DEFUN([BASIC_FIXUP_EXECUTABLE],

   193 [

   194   # Only process if variable expands to non-empty

   195 

   196   if test "x[$]$1" != x; then

   197     if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then

   198       BASIC_FIXUP_EXECUTABLE_CYGWIN($1)

   199     elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then

   200       BASIC_FIXUP_EXECUTABLE_MSYS($1)

   201     else

   202       # We're on a unix platform. Hooray! :)

   203       # First separate the path from the arguments. This will split at the first

   204       # space.

   205       complete="[$]$1"

   206       path="${complete%% *}"

   207       tmp="$complete EOL"

   208       arguments="${tmp#* }"

   209 

   210       # Cannot rely on the command "which" here since it doesn't always work.

   211       is_absolute_path=`$ECHO "$path" | $GREP ^/`

   212       if test -z "$is_absolute_path"; then

   213         # Path to executable is not absolute. Find it.

   214         IFS_save="$IFS"

   215         IFS=:

   216         for p in $PATH; do

   217           if test -f "$p/$path" && test -x "$p/$path"; then

   218             new_path="$p/$path"

   219             break

   220           fi

   221         done

   222         IFS="$IFS_save"

   223       else

   224         # This is an absolute path, we can use it without further modifications.

   225         new_path="$path"

   226       fi

   227 

   228       if test "x$new_path" = x; then

   229         AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])

   230         has_space=`$ECHO "$complete" | $GREP " "`

   231         if test "x$has_space" != x; then

   232           AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])

   233         fi

   234         AC_MSG_ERROR([Cannot locate the the path of $1])

   235       fi

   236     fi

   237 

   238     # Now join together the path and the arguments once again

   239     if test "x$arguments" != xEOL; then

   240       new_complete="$new_path ${arguments% *}"

   241     else

   242       new_complete="$new_path"

   243     fi

   244 

   245     if test "x$complete" != "x$new_complete"; then

   246       $1="$new_complete"

   247       AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])

   248     fi

   249   fi

   250 ])

   251 

   252 AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],

   253 [

   254   if test "x$OPENJDK_BUILD_OS" != xwindows; then

   255     # Follow a chain of symbolic links. Use readlink

   256     # where it exists, else fall back to horribly

   257     # complicated shell code.

   258     if test "x$READLINK_TESTED" != yes; then

   259       # On MacOSX there is a readlink tool with a different

   260       # purpose than the GNU readlink tool. Check the found readlink.

   261       ISGNU=`$READLINK --version 2>&1 | $GREP GNU`

   262       if test "x$ISGNU" = x; then

   263         # A readlink that we do not know how to use.

   264         # Are there other non-GNU readlinks out there?

   265         READLINK_TESTED=yes

   266         READLINK=

   267       fi

   268     fi

   269 

   270     if test "x$READLINK" != x; then

   271       $1=`$READLINK -f [$]$1`

   272     else

   273       # Save the current directory for restoring afterwards

   274       STARTDIR=$PWD

   275       COUNTER=0

   276       sym_link_dir=`$DIRNAME [$]$1`

   277       sym_link_file=`$BASENAME [$]$1`

   278       cd $sym_link_dir

   279       # Use -P flag to resolve symlinks in directories.

   280       cd `$THEPWDCMD -P`

   281       sym_link_dir=`$THEPWDCMD -P`

   282       # Resolve file symlinks

   283       while test $COUNTER -lt 20; do

   284         ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`

   285         if test "x$ISLINK" == x; then

   286           # This is not a symbolic link! We are done!

   287           break

   288         fi

   289         # Again resolve directory symlinks since the target of the just found

   290         # link could be in a different directory

   291         cd `$DIRNAME $ISLINK`

   292         sym_link_dir=`$THEPWDCMD -P`

   293         sym_link_file=`$BASENAME $ISLINK`

   294         let COUNTER=COUNTER+1

   295       done

   296       cd $STARTDIR

   297       $1=$sym_link_dir/$sym_link_file

   298     fi

   299   fi

   300 ])

   301 

   302 # Register a --with argument but mark it as deprecated

   303 # $1: The name of the with argument to deprecate, not including --with-

   304 AC_DEFUN([BASIC_DEPRECATED_ARG_WITH],

   305 [

   306   AC_ARG_WITH($1, [AS_HELP_STRING([--with-$1],

   307       [Deprecated. Option is kept for backwards compatibility and is ignored])],

   308       [AC_MSG_WARN([Option --with-$1 is deprecated and will be ignored.])])

   309 ])

   310 

   311 # Register a --enable argument but mark it as deprecated

   312 # $1: The name of the with argument to deprecate, not including --enable-

   313 # $2: The name of the argument to deprecate, in shell variable style (i.e. with _ instead of -)

   314 # $3: Messages to user.

   315 AC_DEFUN([BASIC_DEPRECATED_ARG_ENABLE],

   316 [

   317   AC_ARG_ENABLE($1, [AS_HELP_STRING([--enable-$1],

   318       [Deprecated. Option is kept for backwards compatibility and is ignored])])

   319   if test "x$enable_$2" != x; then

   320     AC_MSG_WARN([Option --enable-$1 is deprecated and will be ignored.])

   321 

   322     if test "x$3" != x; then

   323       AC_MSG_WARN([$3])

   324     fi

   325 

   326   fi

   327 ])

   328 

   329 AC_DEFUN_ONCE([BASIC_INIT],

   330 [

   331   # Save the original command line. This is passed to us by the wrapper configure script.

   332   AC_SUBST(CONFIGURE_COMMAND_LINE)

   333   # Save the path variable before it gets changed

   334   ORIGINAL_PATH="$PATH"

   335   AC_SUBST(ORIGINAL_PATH)

   336   DATE_WHEN_CONFIGURED=`LANG=C date`

   337   AC_SUBST(DATE_WHEN_CONFIGURED)

   338   AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])

   339   AC_MSG_NOTICE([configure script generated at timestamp $DATE_WHEN_GENERATED.])

   340 ])

   341 

   342 # Test that variable $1 denoting a program is not empty. If empty, exit with an error.

   343 # $1: variable to check

   344 AC_DEFUN([BASIC_CHECK_NONEMPTY],

   345 [

   346   if test "x[$]$1" = x; then

   347     AC_MSG_ERROR([Could not find required tool for $1])

   348   fi

   349 ])

   350 

   351 # Check that there are no unprocessed overridden variables left.

   352 # If so, they are an incorrect argument and we will exit with an error.

   353 AC_DEFUN([BASIC_CHECK_LEFTOVER_OVERRIDDEN],

   354 [

   355   if test "x$CONFIGURE_OVERRIDDEN_VARIABLES" != x; then

   356     # Replace the separating ! with spaces before presenting for end user.

   357     unknown_variables=${CONFIGURE_OVERRIDDEN_VARIABLES//!/ }

   358     AC_MSG_WARN([The following variables might be unknown to configure: $unknown_variables])

   359   fi

   360 ])

   361 

   362 # Setup a tool for the given variable. If correctly specified by the user,

   363 # use that value, otherwise search for the tool using the supplied code snippet.

   364 # $1: variable to set

   365 # $2: code snippet to call to look for the tool

   366 # $3: code snippet to call if variable was used to find tool

   367 AC_DEFUN([BASIC_SETUP_TOOL],

   368 [

   369   # Publish this variable in the help.

   370   AC_ARG_VAR($1, [Override default value for $1])

   371 

   372   if [[ -z "${$1+x}" ]]; then

   373     # The variable is not set by user, try to locate tool using the code snippet

   374     $2

   375   else

   376     # The variable is set, but is it from the command line or the environment?

   377 

   378     # Try to remove the string !$1! from our list.

   379     try_remove_var=${CONFIGURE_OVERRIDDEN_VARIABLES//!$1!/}

   380     if test "x$try_remove_var" = "x$CONFIGURE_OVERRIDDEN_VARIABLES"; then

   381       # If it failed, the variable was not from the command line. Ignore it,

   382       # but warn the user (except for BASH, which is always set by the calling BASH).

   383       if test "x$1" != xBASH; then

   384         AC_MSG_WARN([Ignoring value of $1 from the environment. Use command line variables instead.])

   385       fi

   386       # Try to locate tool using the code snippet

   387       $2

   388     else

   389       # If it succeeded, then it was overridden by the user. We will use it

   390       # for the tool.

   391 

   392       # First remove it from the list of overridden variables, so we can test

   393       # for unknown variables in the end.

   394       CONFIGURE_OVERRIDDEN_VARIABLES="$try_remove_var"

   395 

   396       # Check if we try to supply an empty value

   397       if test "x[$]$1" = x; then

   398         AC_MSG_NOTICE([Setting user supplied tool $1= (no value)])

   399         AC_MSG_CHECKING([for $1])

   400         AC_MSG_RESULT([disabled])

   401       else

   402         # Check if the provided tool contains a complete path.

   403         tool_specified="[$]$1"

   404         tool_basename="${tool_specified##*/}"

   405         if test "x$tool_basename" = "x$tool_specified"; then

   406           # A command without a complete path is provided, search $PATH.

   407           AC_MSG_NOTICE([Will search for user supplied tool $1=$tool_basename])

   408           AC_PATH_PROG($1, $tool_basename)

   409           if test "x[$]$1" = x; then

   410             AC_MSG_ERROR([User supplied tool $tool_basename could not be found])

   411           fi

   412         else

   413           # Otherwise we believe it is a complete path. Use it as it is.

   414           AC_MSG_NOTICE([Will use user supplied tool $1=$tool_specified])

   415           AC_MSG_CHECKING([for $1])

   416           if test ! -x "$tool_specified"; then

   417             AC_MSG_RESULT([not found])

   418             AC_MSG_ERROR([User supplied tool $1=$tool_specified does not exist or is not executable])

   419           fi

   420           AC_MSG_RESULT([$tool_specified])

   421         fi

   422       fi

   423     fi

   424     $3

   425   fi

   426 ])

   427 

   428 # Call BASIC_SETUP_TOOL with AC_PATH_PROGS to locate the tool

   429 # $1: variable to set

   430 # $2: executable name (or list of names) to look for

   431 # $3: [path]

   432 AC_DEFUN([BASIC_PATH_PROGS],

   433 [

   434   BASIC_SETUP_TOOL($1, [AC_PATH_PROGS($1, $2, , $3)])

   435 ])

   436 

   437 # Call BASIC_SETUP_TOOL with AC_CHECK_TOOLS to locate the tool

   438 # $1: variable to set

   439 # $2: executable name (or list of names) to look for

   440 AC_DEFUN([BASIC_CHECK_TOOLS],

   441 [

   442   BASIC_SETUP_TOOL($1, [AC_CHECK_TOOLS($1, $2)])

   443 ])

   444 

   445 # Like BASIC_PATH_PROGS but fails if no tool was found.

   446 # $1: variable to set

   447 # $2: executable name (or list of names) to look for

   448 # $3: [path]

   449 AC_DEFUN([BASIC_REQUIRE_PROGS],

   450 [

   451   BASIC_PATH_PROGS($1, $2, , $3)

   452   BASIC_CHECK_NONEMPTY($1)

   453 ])

   454 

   455 # Like BASIC_SETUP_TOOL but fails if no tool was found.

   456 # $1: variable to set

   457 # $2: autoconf macro to call to look for the special tool

   458 AC_DEFUN([BASIC_REQUIRE_SPECIAL],

   459 [

   460   BASIC_SETUP_TOOL($1, [$2])

   461   BASIC_CHECK_NONEMPTY($1)

   462 ])

   463 

   464 # Setup the most fundamental tools that relies on not much else to set up,

   465 # but is used by much of the early bootstrap code.

   466 AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],

   467 [

   468   # Start with tools that do not need have cross compilation support

   469   # and can be expected to be found in the default PATH. These tools are

   470   # used by configure.

   471 

   472   # First are all the simple required tools.

   473   BASIC_REQUIRE_PROGS(BASENAME, basename)

   474   BASIC_REQUIRE_PROGS(BASH, bash)

   475   BASIC_REQUIRE_PROGS(CAT, cat)

   476   BASIC_REQUIRE_PROGS(CHMOD, chmod)

   477   BASIC_REQUIRE_PROGS(CMP, cmp)

   478   BASIC_REQUIRE_PROGS(COMM, comm)

   479   BASIC_REQUIRE_PROGS(CP, cp)

   480   BASIC_REQUIRE_PROGS(CUT, cut)

   481   BASIC_REQUIRE_PROGS(DATE, date)

   482   BASIC_REQUIRE_PROGS(DIFF, [gdiff diff])

   483   BASIC_REQUIRE_PROGS(DIRNAME, dirname)

   484   BASIC_REQUIRE_PROGS(ECHO, echo)

   485   BASIC_REQUIRE_PROGS(EXPR, expr)

   486   BASIC_REQUIRE_PROGS(FILE, file)

   487   BASIC_REQUIRE_PROGS(FIND, find)

   488   BASIC_REQUIRE_PROGS(HEAD, head)

   489   BASIC_REQUIRE_PROGS(GUNZIP, gunzip)

   490   BASIC_REQUIRE_PROGS(GZIP, pigz gzip)

   491   BASIC_REQUIRE_PROGS(LN, ln)

   492   BASIC_REQUIRE_PROGS(LS, ls)

   493   BASIC_REQUIRE_PROGS(MKDIR, mkdir)

   494   BASIC_REQUIRE_PROGS(MKTEMP, mktemp)

   495   BASIC_REQUIRE_PROGS(MV, mv)

   496   BASIC_REQUIRE_PROGS(NAWK, [nawk gawk awk])

   497   BASIC_REQUIRE_PROGS(PRINTF, printf)

   498   BASIC_REQUIRE_PROGS(RM, rm)

   499   BASIC_REQUIRE_PROGS(RMDIR, rmdir)

   500   BASIC_REQUIRE_PROGS(SH, sh)

   501   BASIC_REQUIRE_PROGS(SORT, sort)

   502   BASIC_REQUIRE_PROGS(TAIL, tail)

   503   BASIC_REQUIRE_PROGS(TAR, gtar tar)

   504   BASIC_REQUIRE_PROGS(TEE, tee)

   505   BASIC_REQUIRE_PROGS(TOUCH, touch)

   506   BASIC_REQUIRE_PROGS(TR, tr)

   507   BASIC_REQUIRE_PROGS(UNAME, uname)

   508   BASIC_REQUIRE_PROGS(UNIQ, uniq)

   509   BASIC_REQUIRE_PROGS(WC, wc)

   510   BASIC_REQUIRE_PROGS(WHICH, which)

   511   BASIC_REQUIRE_PROGS(XARGS, xargs)

   512 

   513   # Then required tools that require some special treatment.

   514   BASIC_REQUIRE_SPECIAL(AWK, [AC_PROG_AWK])

   515   BASIC_REQUIRE_SPECIAL(GREP, [AC_PROG_GREP])

   516   BASIC_REQUIRE_SPECIAL(EGREP, [AC_PROG_EGREP])

   517   BASIC_REQUIRE_SPECIAL(FGREP, [AC_PROG_FGREP])

   518   BASIC_REQUIRE_SPECIAL(SED, [AC_PROG_SED])

   519 

   520   # Always force rm.

   521   RM="$RM -f"

   522 

   523   # pwd behaves differently on various platforms and some don't support the -L flag.

   524   # Always use the bash builtin pwd to get uniform behavior.

   525   THEPWDCMD=pwd

   526 

   527   # These are not required on all platforms

   528   BASIC_PATH_PROGS(CYGPATH, cygpath)

   529   BASIC_PATH_PROGS(READLINK, [greadlink readlink])

   530   BASIC_PATH_PROGS(DF, df)

   531   BASIC_PATH_PROGS(CPIO, [cpio bsdcpio])

   532   BASIC_PATH_PROGS(NICE, nice)

   533   BASIC_PATH_PROGS(PANDOC, pandoc)

   534 ])

   535 

   536 # Setup basic configuration paths, and platform-specific stuff related to PATHs.

   537 AC_DEFUN_ONCE([BASIC_SETUP_PATHS],

   538 [

   539   # Save the current directory this script was started from

   540   CURDIR="$PWD"

   541 

   542   # We might need to rewrite ORIGINAL_PATH, if it includes "#", to quote them

   543   # for make. We couldn't do this when we retrieved ORIGINAL_PATH, since SED

   544   # was not available at that time.

   545   REWRITTEN_PATH=`$ECHO "$ORIGINAL_PATH" | $SED -e 's/#/\\\\#/g'`

   546   if test "x$REWRITTEN_PATH" != "x$ORIGINAL_PATH"; then

   547     ORIGINAL_PATH="$REWRITTEN_PATH"

   548     AC_MSG_NOTICE([Rewriting ORIGINAL_PATH to $REWRITTEN_PATH])

   549   fi

   550 

   551   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then

   552     PATH_SEP=";"

   553     BASIC_CHECK_PATHS_WINDOWS

   554   else

   555     PATH_SEP=":"

   556   fi

   557   AC_SUBST(PATH_SEP)

   558 

   559   # We get the top-level directory from the supporting wrappers.

   560   AC_MSG_CHECKING([for top-level directory])

   561   AC_MSG_RESULT([$TOPDIR])

   562   AC_SUBST(TOPDIR)

   563 

   564   # Save the original version of TOPDIR for string comparisons

   565   ORIGINAL_TOPDIR="$TOPDIR"

   566   AC_SUBST(ORIGINAL_TOPDIR)

   567 

   568   # We can only call BASIC_FIXUP_PATH after BASIC_CHECK_PATHS_WINDOWS.

   569   BASIC_FIXUP_PATH(CURDIR)

   570   BASIC_FIXUP_PATH(TOPDIR)

   571   # SRC_ROOT is a traditional alias for TOPDIR.

   572   SRC_ROOT=$TOPDIR

   573 

   574   # Calculate a canonical version of TOPDIR for string comparisons

   575   CANONICAL_TOPDIR=$TOPDIR

   576   BASIC_REMOVE_SYMBOLIC_LINKS([CANONICAL_TOPDIR])

   577   AC_SUBST(CANONICAL_TOPDIR)

   578 

   579   # Locate the directory of this script.

   580   AUTOCONF_DIR=$TOPDIR/common/autoconf

   581 

   582   # Setup username (for use in adhoc version strings etc)

   583   # Outer [ ] to quote m4.

   584   [ USERNAME=`$ECHO "$USER" | $TR -d -c '[a-z][A-Z][0-9]'` ]

   585   AC_SUBST(USERNAME)

   586 ])

   587 

   588 # Evaluates platform specific overrides for devkit variables.

   589 # $1: Name of variable

   590 AC_DEFUN([BASIC_EVAL_DEVKIT_VARIABLE],

   591 [

   592   if test "x[$]$1" = x; then

   593     eval $1="\${$1_${OPENJDK_TARGET_CPU}}"

   594   fi

   595 ])

   596 

   597 AC_DEFUN_ONCE([BASIC_SETUP_DEVKIT],

   598 [

   599   AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],

   600       [use this devkit for compilers, tools and resources])],

   601       [

   602         BASIC_FIXUP_PATH([with_devkit])

   603         DEVKIT_ROOT="$with_devkit"

   604         # Check for a meta data info file in the root of the devkit

   605         if test -f "$DEVKIT_ROOT/devkit.info"; then

   606           . $DEVKIT_ROOT/devkit.info

   607           # This potentially sets the following:

   608           # A descriptive name of the devkit

   609           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_NAME])

   610           # Corresponds to --with-extra-path

   611           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_EXTRA_PATH])

   612           # Corresponds to --with-toolchain-path

   613           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_TOOLCHAIN_PATH])

   614           # Corresponds to --with-sysroot

   615           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_SYSROOT])

   616 

   617           # Identifies the Visual Studio version in the devkit

   618           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_VERSION])

   619           # The Visual Studio include environment variable

   620           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_INCLUDE])

   621           # The Visual Studio lib environment variable

   622           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_LIB])

   623           # Corresponds to --with-msvcr-dll

   624           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_MSVCR_DLL])

   625           # Corresponds to --with-msvcp-dll

   626           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_MSVCP_DLL])

   627         fi

   628 

   629         AC_MSG_CHECKING([for devkit])

   630         if test "x$DEVKIT_NAME" != x; then

   631           AC_MSG_RESULT([$DEVKIT_NAME in $DEVKIT_ROOT])

   632         else

   633           AC_MSG_RESULT([$DEVKIT_ROOT])

   634         fi

   635 

   636         BASIC_PREPEND_TO_PATH([EXTRA_PATH],$DEVKIT_EXTRA_PATH)

   637 

   638         # Fallback default of just /bin if DEVKIT_PATH is not defined

   639         if test "x$DEVKIT_TOOLCHAIN_PATH" = x; then

   640           DEVKIT_TOOLCHAIN_PATH="$DEVKIT_ROOT/bin"

   641         fi

   642         BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$DEVKIT_TOOLCHAIN_PATH)

   643 

   644         # If DEVKIT_SYSROOT is set, use that, otherwise try a couple of known

   645         # places for backwards compatiblity.

   646         if test "x$DEVKIT_SYSROOT" != x; then

   647           SYSROOT="$DEVKIT_SYSROOT"

   648         elif test -d "$DEVKIT_ROOT/$host_alias/libc"; then

   649           SYSROOT="$DEVKIT_ROOT/$host_alias/libc"

   650         elif test -d "$DEVKIT_ROOT/$host/sys-root"; then

   651           SYSROOT="$DEVKIT_ROOT/$host/sys-root"

   652         fi

   653       ]

   654   )

   655 

   656   # You can force the sysroot if the sysroot encoded into the compiler tools

   657   # is not correct.

   658   AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],

   659       [alias for --with-sysroot for backwards compatability])],

   660       [SYSROOT=$with_sys_root]

   661   )

   662 

   663   AC_ARG_WITH(sysroot, [AS_HELP_STRING([--with-sysroot],

   664       [use this directory as sysroot])],

   665       [SYSROOT=$with_sysroot]

   666   )

   667 

   668   AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],

   669       [alias for --with-toolchain-path for backwards compatibility])],

   670       [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_tools_dir)]

   671   )

   672 

   673   AC_ARG_WITH([toolchain-path], [AS_HELP_STRING([--with-toolchain-path],

   674       [prepend these directories when searching for toolchain binaries (compilers etc)])],

   675       [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_toolchain_path)]

   676   )

   677 

   678   AC_ARG_WITH([extra-path], [AS_HELP_STRING([--with-extra-path],

   679       [prepend these directories to the default path])],

   680       [BASIC_PREPEND_TO_PATH([EXTRA_PATH],$with_extra_path)]

   681   )

   682 

   683   if test "x$OPENJDK_BUILD_OS" = "xmacosx"; then

   684     # If a devkit has been supplied, find xcodebuild in the toolchain_path.

   685     # If not, detect if Xcode is installed by running xcodebuild -version

   686     # if no Xcode installed, xcodebuild exits with 1

   687     # if Xcode is installed, even if xcode-select is misconfigured, then it exits with 0

   688     if test "x$DEVKIT_ROOT" != x || /usr/bin/xcodebuild -version >/dev/null 2>&1; then

   689       # We need to use xcodebuild in the toolchain dir provided by the user, this will

   690       # fall back on the stub binary in /usr/bin/xcodebuild

   691       AC_PATH_PROG([XCODEBUILD], [xcodebuild], [/usr/bin/xcodebuild], [$TOOLCHAIN_PATH])

   692     else

   693       # this should result in SYSROOT being empty, unless --with-sysroot is provided

   694       # when only the command line tools are installed there are no SDKs, so headers

   695       # are copied into the system frameworks

   696       XCODEBUILD=

   697       AC_SUBST(XCODEBUILD)

   698     fi

   699 

   700     AC_MSG_CHECKING([for sdk name])

   701     AC_ARG_WITH([sdk-name], [AS_HELP_STRING([--with-sdk-name],

   702         [use the platform SDK of the given name. @<:@macosx@:>@])],

   703         [SDKNAME=$with_sdk_name]

   704     )

   705     AC_MSG_RESULT([$SDKNAME])

   706 

   707     # if toolchain path is specified then don't rely on system headers, they may not compile

   708     HAVE_SYSTEM_FRAMEWORK_HEADERS=0

   709     test -z "$TOOLCHAIN_PATH" && \

   710       HAVE_SYSTEM_FRAMEWORK_HEADERS=`test ! -f /System/Library/Frameworks/Foundation.framework/Headers/Foundation.h; echo $?`

   711 

   712     if test -z "$SYSROOT"; then

   713       if test -n "$XCODEBUILD"; then

   714         # if we don't have system headers, use default SDK name (last resort)

   715         if test -z "$SDKNAME" -a $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then

   716           SDKNAME=${SDKNAME:-macosx}

   717         fi

   718 

   719         if test -n "$SDKNAME"; then

   720           # Call xcodebuild to determine SYSROOT

   721           SYSROOT=`"$XCODEBUILD" -sdk $SDKNAME -version | $GREP '^Path: ' | $SED 's/Path: //'`

   722         fi

   723       else

   724         if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then

   725           AC_MSG_ERROR([No xcodebuild tool and no system framework headers found, use --with-sysroot or --with-sdk-name to provide a path to a valid SDK])

   726         fi

   727       fi

   728     else

   729       # warn user if --with-sdk-name was also set

   730       if test -n "$with_sdk_name"; then

   731         AC_MSG_WARN([Both SYSROOT and --with-sdk-name are set, only SYSROOT will be used])

   732       fi

   733     fi

   734 

   735     if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0 -a -z "$SYSROOT"; then

   736       # If no system framework headers, then SYSROOT must be set, or we won't build

   737       AC_MSG_ERROR([Unable to determine SYSROOT and no headers found in /System/Library/Frameworks. Check Xcode configuration, --with-sysroot or --with-sdk-name arguments.])

   738     fi

   739 

   740     # Perform a basic sanity test

   741     if test ! -f "$SYSROOT/System/Library/Frameworks/Foundation.framework/Headers/Foundation.h"; then

   742       if test -z "$SYSROOT"; then

   743         AC_MSG_ERROR([Unable to find required framework headers, provide a path to an SDK via --with-sysroot or --with-sdk-name and be sure Xcode is installed properly])

   744       else

   745         AC_MSG_ERROR([Invalid SDK or SYSROOT path, dependent framework headers not found])

   746       fi

   747     fi

   748 

   749     # set SDKROOT too, Xcode tools will pick it up

   750     SDKROOT="$SYSROOT"

   751     AC_SUBST(SDKROOT)

   752   fi

   753 

   754   # Prepend the extra path to the global path

   755   BASIC_PREPEND_TO_PATH([PATH],$EXTRA_PATH)

   756 

   757   AC_MSG_CHECKING([for sysroot])

   758   AC_MSG_RESULT([$SYSROOT])

   759   AC_MSG_CHECKING([for toolchain path])

   760   AC_MSG_RESULT([$TOOLCHAIN_PATH])

   761   AC_MSG_CHECKING([for extra path])

   762   AC_MSG_RESULT([$EXTRA_PATH])

   763 ])

   764 

   765 AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],

   766 [

   767 

   768   AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],

   769       [use this as the name of the configuration @<:@generated from important configuration options@:>@])],

   770       [ CONF_NAME=${with_conf_name} ])

   771 

   772   # Test from where we are running configure, in or outside of src root.

   773   AC_MSG_CHECKING([where to store configuration])

   774   if test "x$CURDIR" = "x$SRC_ROOT" || test "x$CURDIR" = "x$SRC_ROOT/common" \

   775       || test "x$CURDIR" = "x$SRC_ROOT/common/autoconf" \

   776       || test "x$CURDIR" = "x$SRC_ROOT/make" ; then

   777     # We are running configure from the src root.

   778     # Create a default ./build/target-variant-debuglevel output root.

   779     if test "x${CONF_NAME}" = x; then

   780       AC_MSG_RESULT([in default location])

   781       CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JDK_VARIANT}-${JVM_VARIANTS_WITH_AND}-${DEBUG_LEVEL}"

   782     else

   783       AC_MSG_RESULT([in build directory with custom name])

   784     fi

   785     OUTPUT_ROOT="$SRC_ROOT/build/${CONF_NAME}"

   786     $MKDIR -p "$OUTPUT_ROOT"

   787     if test ! -d "$OUTPUT_ROOT"; then

   788       AC_MSG_ERROR([Could not create build directory $OUTPUT_ROOT])

   789     fi

   790   else

   791     # We are running configure from outside of the src dir.

   792     # Then use the current directory as output dir!

   793     # If configuration is situated in normal build directory, just use the build

   794     # directory name as configuration name, otherwise use the complete path.

   795     if test "x${CONF_NAME}" = x; then

   796       CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${SRC_ROOT}/build/!!"`

   797     fi

   798     OUTPUT_ROOT="$CURDIR"

   799     AC_MSG_RESULT([in current directory])

   800 

   801     # WARNING: This might be a bad thing to do. You need to be sure you want to

   802     # have a configuration in this directory. Do some sanity checks!

   803 

   804     if test ! -e "$OUTPUT_ROOT/spec.gmk"; then

   805       # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for

   806       # other files

   807       files_present=`$LS $OUTPUT_ROOT`

   808       # Configure has already touched config.log and confdefs.h in the current dir when this check

   809       # is performed.

   810       filtered_files=`$ECHO "$files_present" \

   811           | $SED -e 's/config.log//g' \

   812               -e 's/configure.log//g' \

   813               -e 's/confdefs.h//g' \

   814               -e 's/ //g' \

   815           | $TR -d '\n'`

   816       if test "x$filtered_files" != x; then

   817         AC_MSG_NOTICE([Current directory is $CURDIR.])

   818         AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])

   819         AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])

   820         AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])

   821         AC_MSG_NOTICE([seriously mess up just about everything.])

   822         AC_MSG_NOTICE([Try 'cd $SRC_ROOT' and restart configure])

   823         AC_MSG_NOTICE([(or create a new empty directory and cd to it).])

   824         AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])

   825       fi

   826     fi

   827   fi

   828   AC_MSG_CHECKING([what configuration name to use])

   829   AC_MSG_RESULT([$CONF_NAME])

   830 

   831   BASIC_FIXUP_PATH(OUTPUT_ROOT)

   832 

   833   CONFIGURESUPPORT_OUTPUTDIR="$OUTPUT_ROOT/configure-support"

   834   $MKDIR -p "$CONFIGURESUPPORT_OUTPUTDIR"

   835 

   836   SPEC="$OUTPUT_ROOT/spec.gmk"

   837   AC_SUBST(SPEC)

   838   AC_SUBST(CONF_NAME)

   839   AC_SUBST(OUTPUT_ROOT)

   840   AC_SUBST(CONFIGURESUPPORT_OUTPUTDIR)

   841 

   842   # The spec.gmk file contains all variables for the make system.

   843   AC_CONFIG_FILES([$OUTPUT_ROOT/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])

   844   # The bootcycle-spec.gmk file contains support for boot cycle builds.

   845   AC_CONFIG_FILES([$OUTPUT_ROOT/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])

   846   # The buildjdk-spec.gmk file contains support for building a buildjdk when cross compiling.

   847   AC_CONFIG_FILES([$OUTPUT_ROOT/buildjdk-spec.gmk:$AUTOCONF_DIR/buildjdk-spec.gmk.in])

   848   # The compare.sh is used to compare the build output to other builds.

   849   AC_CONFIG_FILES([$OUTPUT_ROOT/compare.sh:$AUTOCONF_DIR/compare.sh.in])

   850   # The generated Makefile knows where the spec.gmk is and where the source is.

   851   # You can run make from the OUTPUT_ROOT, or from the top-level Makefile

   852   # which will look for generated configurations

   853   AC_CONFIG_FILES([$OUTPUT_ROOT/Makefile:$AUTOCONF_DIR/Makefile.in])

   854 ])

   855 

   856 #%%% Simple tools %%%

   857 

   858 # Check if we have found a usable version of make

   859 # $1: the path to a potential make binary (or empty)

   860 # $2: the description on how we found this

   861 AC_DEFUN([BASIC_CHECK_MAKE_VERSION],

   862 [

   863   MAKE_CANDIDATE="$1"

   864   DESCRIPTION="$2"

   865 

   866   # On Cygwin, we require a newer version of make than on other platforms

   867   if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then

   868     MAKE_VERSION_EXPR="-e 4\."

   869     MAKE_REQUIRED_VERSION="4.0"

   870    else

   871     MAKE_VERSION_EXPR="-e 3\.8[[12]] -e 4\."

   872     MAKE_REQUIRED_VERSION="3.81"

   873   fi

   874 

   875   if test "x$MAKE_CANDIDATE" != x; then

   876     AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])

   877     MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`

   878     IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`

   879     if test "x$IS_GNU_MAKE" = x; then

   880       AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])

   881     else

   882       IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP $MAKE_VERSION_EXPR`

   883       if test "x$IS_MODERN_MAKE" = x; then

   884         AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version $MAKE_REQUIRED_VERSION or later. (it is: $MAKE_VERSION_STRING). Ignoring.])

   885       else

   886         if test "x$OPENJDK_BUILD_OS" = "xwindows"; then

   887           if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then

   888             MAKE_EXPECTED_ENV='cygwin'

   889           elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then

   890             MAKE_EXPECTED_ENV='msys'

   891           else

   892             AC_MSG_ERROR([Unknown Windows environment])

   893           fi

   894           MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`

   895           IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`

   896         else

   897           # Not relevant for non-Windows

   898           IS_MAKE_CORRECT_ENV=true

   899         fi

   900         if test "x$IS_MAKE_CORRECT_ENV" = x; then

   901           AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])

   902         else

   903           FOUND_MAKE=$MAKE_CANDIDATE

   904           BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)

   905         fi

   906       fi

   907     fi

   908   fi

   909 ])

   910 

   911 AC_DEFUN([BASIC_CHECK_MAKE_OUTPUT_SYNC],

   912 [

   913   # Check if make supports the output sync option and if so, setup using it.

   914   AC_MSG_CHECKING([if make --output-sync is supported])

   915   if $MAKE --version -O > /dev/null 2>&1; then

   916     OUTPUT_SYNC_SUPPORTED=true

   917     AC_MSG_RESULT([yes])

   918     AC_MSG_CHECKING([for output-sync value])

   919     AC_ARG_WITH([output-sync], [AS_HELP_STRING([--with-output-sync],

   920       [set make output sync type if supported by make. @<:@recurse@:>@])],

   921       [OUTPUT_SYNC=$with_output_sync])

   922     if test "x$OUTPUT_SYNC" = "x"; then

   923       OUTPUT_SYNC=none

   924     fi

   925     AC_MSG_RESULT([$OUTPUT_SYNC])

   926     if ! $MAKE --version -O$OUTPUT_SYNC > /dev/null 2>&1; then

   927       AC_MSG_ERROR([Make did not the support the value $OUTPUT_SYNC as output sync type.])

   928     fi

   929   else

   930     OUTPUT_SYNC_SUPPORTED=false

   931     AC_MSG_RESULT([no])

   932   fi

   933   AC_SUBST(OUTPUT_SYNC_SUPPORTED)

   934   AC_SUBST(OUTPUT_SYNC)

   935 ])

   936 

   937 # Goes looking for a usable version of GNU make.

   938 AC_DEFUN([BASIC_CHECK_GNU_MAKE],

   939 [

   940   BASIC_SETUP_TOOL([MAKE],

   941   [

   942     # Try our hardest to locate a correct version of GNU make

   943     AC_PATH_PROGS(CHECK_GMAKE, gmake)

   944     BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])

   945 

   946     if test "x$FOUND_MAKE" = x; then

   947       AC_PATH_PROGS(CHECK_MAKE, make)

   948       BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])

   949     fi

   950 

   951     if test "x$FOUND_MAKE" = x; then

   952       if test "x$TOOLCHAIN_PATH" != x; then

   953         # We have a toolchain path, check that as well before giving up.

   954         OLD_PATH=$PATH

   955         PATH=$TOOLCHAIN_PATH:$PATH

   956         AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)

   957         BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])

   958         if test "x$FOUND_MAKE" = x; then

   959           AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)

   960           BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])

   961         fi

   962         PATH=$OLD_PATH

   963       fi

   964     fi

   965 

   966     if test "x$FOUND_MAKE" = x; then

   967       AC_MSG_ERROR([Cannot find GNU make $MAKE_REQUIRED_VERSION or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])

   968     fi

   969   ],[

   970     # If MAKE was set by user, verify the version

   971     BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])

   972     if test "x$FOUND_MAKE" = x; then

   973       AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make $MAKE_REQUIRED_VERSION or newer.])

   974     fi

   975   ])

   976 

   977   MAKE=$FOUND_MAKE

   978   AC_SUBST(MAKE)

   979   AC_MSG_NOTICE([Using GNU make at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])

   980 

   981   BASIC_CHECK_MAKE_OUTPUT_SYNC

   982 ])

   983 

   984 AC_DEFUN([BASIC_CHECK_FIND_DELETE],

   985 [

   986   # Test if find supports -delete

   987   AC_MSG_CHECKING([if find supports -delete])

   988   FIND_DELETE="-delete"

   989 

   990   DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)

   991 

   992   echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete

   993 

   994   TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`

   995   if test -f $DELETEDIR/TestIfFindSupportsDelete; then

   996     # No, it does not.

   997     $RM $DELETEDIR/TestIfFindSupportsDelete

   998     if test "x$OPENJDK_TARGET_OS" = "xaix"; then

   999       # AIX 'find' is buggy if called with '-exec {} \+' and an empty file list

  1000       FIND_DELETE="-print | $XARGS $RM"

  1001     else

  1002       FIND_DELETE="-exec $RM \{\} \+"

  1003     fi

  1004     AC_MSG_RESULT([no])

  1005   else

  1006     AC_MSG_RESULT([yes])

  1007   fi

  1008   $RMDIR $DELETEDIR

  1009   AC_SUBST(FIND_DELETE)

  1010 ])

  1011 

  1012 AC_DEFUN([BASIC_CHECK_TAR],

  1013 [

  1014   # Test which kind of tar was found

  1015   if test "x$($TAR --version | $GREP "GNU tar")" != "x"; then

  1016     TAR_TYPE="gnu"

  1017   elif test "x$($TAR --version | $GREP "bsdtar")" != "x"; then

  1018     TAR_TYPE="bsd"

  1019   elif test "x$($TAR -v | $GREP "bsdtar")" != "x"; then

  1020     TAR_TYPE="bsd"

  1021   elif test "x$OPENJDK_BUILD_OS" = "xsolaris"; then

  1022     TAR_TYPE="solaris"

  1023   fi

  1024   AC_MSG_CHECKING([what type of tar was found])

  1025   AC_MSG_RESULT([$TAR_TYPE])

  1026 

  1027   TAR_CREATE_FILE_PARAM=""

  1028 

  1029   if test "x$TAR_TYPE" = "xgnu"; then

  1030     TAR_INCLUDE_PARAM="T"

  1031     TAR_SUPPORTS_TRANSFORM="true"

  1032     if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then

  1033       # When using gnu tar for Solaris targets, need to use compatibility mode

  1034       TAR_CREATE_EXTRA_PARAM="--format=ustar"

  1035     fi

  1036   else

  1037     TAR_INCLUDE_PARAM="I"

  1038     TAR_SUPPORTS_TRANSFORM="false"

  1039   fi

  1040   AC_SUBST(TAR_TYPE)

  1041   AC_SUBST(TAR_CREATE_EXTRA_PARAM)

  1042   AC_SUBST(TAR_INCLUDE_PARAM)

  1043   AC_SUBST(TAR_SUPPORTS_TRANSFORM)

  1044 ])

  1045 

  1046 AC_DEFUN([BASIC_CHECK_GREP],

  1047 [

  1048   # Test that grep supports -Fx with a list of pattern which includes null pattern.

  1049   # This is a problem for the grep resident on AIX.

  1050   AC_MSG_CHECKING([that grep ($GREP) -Fx handles empty lines in the pattern list correctly])

  1051   # Multiple subsequent spaces..

  1052   STACK_SPACES='aaa   bbb   ccc'

  1053   # ..converted to subsequent newlines, causes STACK_LIST to be a list with some empty

  1054   # patterns in it.

  1055   STACK_LIST=${STACK_SPACES// /$'\n'}

  1056   NEEDLE_SPACES='ccc bbb aaa'

  1057   NEEDLE_LIST=${NEEDLE_SPACES// /$'\n'}

  1058   RESULT="$($GREP -Fvx "$STACK_LIST" <<< "$NEEDLE_LIST")"

  1059   if test "x$RESULT" == "x"; then

  1060     AC_MSG_RESULT([yes])

  1061   else

  1062     if test "x$OPENJDK_TARGET_OS" = "xaix"; then

  1063       ADDINFO="Please make sure you use GNU grep, usually found at /opt/freeware/bin."

  1064     fi

  1065     AC_MSG_ERROR([grep does not handle -Fx correctly. ${ADDINFO}])

  1066   fi

  1067 ])

  1068 

  1069 AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],

  1070 [

  1071   BASIC_CHECK_GNU_MAKE

  1072 

  1073   BASIC_CHECK_FIND_DELETE

  1074   BASIC_CHECK_TAR

  1075   BASIC_CHECK_GREP

  1076 

  1077   # These tools might not be installed by default,

  1078   # need hint on how to install them.

  1079   BASIC_REQUIRE_PROGS(UNZIP, unzip)

  1080   # Since zip uses "ZIP" as a environment variable for passing options, we need

  1081   # to name our variable differently, hence ZIPEXE.

  1082   BASIC_REQUIRE_PROGS(ZIPEXE, zip)

  1083 

  1084   # Non-required basic tools

  1085 

  1086   BASIC_PATH_PROGS(LDD, ldd)

  1087   if test "x$LDD" = "x"; then

  1088     # List shared lib dependencies is used for

  1089     # debug output and checking for forbidden dependencies.

  1090     # We can build without it.

  1091     LDD="true"

  1092   fi

  1093   BASIC_PATH_PROGS(OTOOL, otool)

  1094   if test "x$OTOOL" = "x"; then

  1095     OTOOL="true"

  1096   fi

  1097   BASIC_PATH_PROGS(READELF, [greadelf readelf])

  1098   BASIC_PATH_PROGS(DOT, dot)

  1099   BASIC_PATH_PROGS(HG, hg)

  1100   BASIC_PATH_PROGS(STAT, stat)

  1101   BASIC_PATH_PROGS(TIME, time)

  1102   BASIC_PATH_PROGS(FLOCK, flock)

  1103   # Dtrace is usually found in /usr/sbin on Solaris, but that directory may not

  1104   # be in the user path.

  1105   BASIC_PATH_PROGS(DTRACE, dtrace, $PATH:/usr/sbin)

  1106   BASIC_PATH_PROGS(PATCH, [gpatch patch])

  1107   # Check if it's GNU time

  1108   IS_GNU_TIME=`$TIME --version 2>&1 | $GREP 'GNU time'`

  1109   if test "x$IS_GNU_TIME" != x; then

  1110     IS_GNU_TIME=yes

  1111   else

  1112     IS_GNU_TIME=no

  1113   fi

  1114   AC_SUBST(IS_GNU_TIME)

  1115 

  1116   if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then

  1117     BASIC_REQUIRE_PROGS(DSYMUTIL, dsymutil)

  1118     BASIC_REQUIRE_PROGS(XATTR, xattr)

  1119     BASIC_PATH_PROGS(CODESIGN, codesign)

  1120     if test "x$CODESIGN" != "x"; then

  1121       # Verify that the openjdk_codesign certificate is present

  1122       AC_MSG_CHECKING([if openjdk_codesign certificate is present])

  1123       $RM codesign-testfile

  1124       $TOUCH codesign-testfile

  1125       $CODESIGN -s openjdk_codesign codesign-testfile 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD || CODESIGN=

  1126       $RM codesign-testfile

  1127       if test "x$CODESIGN" = x; then

  1128         AC_MSG_RESULT([no])

  1129       else

  1130         AC_MSG_RESULT([yes])

  1131       fi

  1132     fi

  1133     BASIC_REQUIRE_PROGS(SETFILE, SetFile)

  1134   fi