<?xml version="1.0" encoding="utf-8"?>

<!--

 Copyright (c) 2002, 2012, Oracle and/or its affiliates. All rights reserved.

 DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.

 This code is free software; you can redistribute it and/or modify it

 under the terms of the GNU General Public License version 2 only, as

 published by the Free Software Foundation.

 This code is distributed in the hope that it will be useful, but WITHOUT

 ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or

 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License

 version 2 for more details (a copy is included in the LICENSE file that

 accompanied this code).

 You should have received a copy of the GNU General Public License version

 2 along with this work; if not, write to the Free Software Foundation,

 Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.

 Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA

 or visit www.oracle.com if you need additional information or have any

 questions.

-->

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"

                version="1.0">

  <xsl:template name="microversion">

    <xsl:value-of select="//specification/@microversion"/>

  </xsl:template>

  <xsl:template name="showbasicversion">

    <xsl:value-of select="//specification/@majorversion"/>

    <xsl:text>.</xsl:text>

    <xsl:value-of select="//specification/@minorversion"/>

  </xsl:template>

  <xsl:template name="showversion">

    <xsl:call-template name="showbasicversion"/>

    <xsl:text>.</xsl:text>

    <xsl:call-template name="microversion"/>

  </xsl:template>

  <xsl:template name="copyrightComment">

    <xsl:text>/* </xsl:text>

    <!-- Copy the Copyright comment from jvmti.xml -->

    <xsl:value-of select="/comment()[position()=1]"/>

    <xsl:text> */ &#xA;&#xA;</xsl:text>

  </xsl:template>

  <xsl:template name="includeHeader">

    <xsl:call-template name="copyrightComment"/>

    <xsl:text> /* AUTOMATICALLY GENERATED FILE - DO NOT EDIT */ &#xA;</xsl:text>    

  </xsl:template>

  <xsl:template name="sourceHeader">

    <xsl:call-template name="copyrightComment"/>

    <xsl:text> // AUTOMATICALLY GENERATED FILE - DO NOT EDIT &#xA;</xsl:text>    

  </xsl:template>

<xsl:template match="parameters" mode="signature">

  <xsl:param name="comma">

    <xsl:text>,

            </xsl:text>

  </xsl:param>

  <xsl:if test="count(param) != 0">

    <xsl:value-of select="$comma"/>

  </xsl:if>

  <xsl:apply-templates select="." mode="signaturenoleadcomma">

    <xsl:with-param name="comma" select="$comma"/>

  </xsl:apply-templates>

</xsl:template>

<xsl:template match="parameters" mode="signaturenoleadcomma">

  <xsl:param name="comma">

    <xsl:text>,

            </xsl:text>

  </xsl:param>

  <xsl:variable name="length" select="count(param)"/>

  <xsl:for-each select="param">

    <xsl:variable name="separator">

        <xsl:choose>

          <xsl:when test="position()=$length">

            <xsl:text></xsl:text>

          </xsl:when>

          <xsl:otherwise>

            <xsl:value-of select="$comma"/>

          </xsl:otherwise>

        </xsl:choose>

    </xsl:variable>

    <xsl:apply-templates select="." mode="signature">

      <xsl:with-param name="comma" select="$separator"/>

    </xsl:apply-templates>

  </xsl:for-each>

</xsl:template>

<!-- remove jclass parameters that are jclass/jmethodID pairs.

     since the jclass was removed in JVMTI.

-->

<xsl:template match="param" mode="signature">

  <xsl:param name="comma"/>

  <xsl:variable name="id" select="@id"/>

  <xsl:for-each select="child::*[position()=1]">

    <xsl:if test="count(@method)=0">

      <xsl:apply-templates select="." mode="signature"/>

      <xsl:text> </xsl:text>

      <xsl:value-of select="$id"/>

      <xsl:value-of select="$comma"/>

    </xsl:if>

  </xsl:for-each>

</xsl:template>

<xsl:template match="field" mode="signature">

  <xsl:text>    </xsl:text>

  <xsl:apply-templates select="child::*[position()=1]" mode="signature"/>

  <xsl:text> </xsl:text>

  <xsl:value-of select="@id"/>

  <xsl:text>;

</xsl:text>

</xsl:template>

<xsl:template match="nullok" mode="funcdescription">

  If

  <code>

    <xsl:value-of select="../../@id"/>

  </code>

  is

  <code>NULL</code>, <xsl:apply-templates/>.

</xsl:template>

<xsl:template match="vmbuf|allocfieldbuf|struct" mode="funcdescription">

  <xsl:message terminate="yes">

    vmbuf|allocfieldbuf|struct as type of function parameter

  </xsl:message>

</xsl:template>

<xsl:template match="ptrtype" mode="funcdescription">

  <p/>

  <xsl:apply-templates select="nullok" mode="funcdescription"/>

</xsl:template>

<xsl:template match="inptr" mode="funcdescription">

  <p/>

  <xsl:variable name="child" select="child::*[position()=1]"/>

  <xsl:text>Agent passes in a pointer</xsl:text>

  <xsl:if test="name($child)!='void'">

    <xsl:text> to </xsl:text>

    <code>

      <xsl:apply-templates select="$child" mode="signature"/> 

    </code>

  </xsl:if>

  <xsl:text>. </xsl:text>

  <xsl:apply-templates select="nullok" mode="funcdescription"/>

</xsl:template>

<xsl:template match="inbuf" mode="funcdescription">

  <p/>

  <xsl:variable name="child" select="child::*[position()=1]"/>

  <xsl:text>Agent passes in </xsl:text>

  <xsl:choose>

    <xsl:when test="name($child)='void'">

      <xsl:text> a pointer</xsl:text>

    </xsl:when>

    <xsl:otherwise>

      <xsl:text> an array of </xsl:text>

      <xsl:if test="count(@incount)=1 and @incount!=''">

        <code>

          <xsl:value-of select="@incount"/>

        </code>

        <xsl:text> elements of </xsl:text>

      </xsl:if>

      <code>

        <xsl:apply-templates select="$child" mode="signature"/> 

      </code>

    </xsl:otherwise>

  </xsl:choose>

  <xsl:text>. </xsl:text>

  <xsl:apply-templates select="nullok" mode="funcdescription"/>

</xsl:template>

<xsl:template match="outptr" mode="funcdescription">

  <p/>

  <xsl:text>Agent passes a pointer to a </xsl:text>

  <code>

    <xsl:apply-templates select="child::*[position()=1]" mode="signature"/> 

  </code>

  <xsl:text>. </xsl:text>

  <xsl:text>On return, the </xsl:text>

  <code>

    <xsl:apply-templates select="child::*[position()=1]" mode="signature"/> 

  </code>

  <xsl:text> has been set. </xsl:text>

  <xsl:apply-templates select="nullok" mode="funcdescription"/>

  <xsl:apply-templates select="child::*[position()=1]" mode="returndescription"/>

</xsl:template>

<xsl:template match="allocbuf" mode="funcdescription">

  <p/>

  <xsl:text>Agent passes a pointer to a </xsl:text>

  <code>

    <xsl:apply-templates select="child::*[position()=1]" mode="signature"/> 

    <xsl:text>*</xsl:text>

  </code>

  <xsl:text>. </xsl:text>

  <xsl:text>On return, the </xsl:text>

  <code>

    <xsl:apply-templates select="child::*[position()=1]" mode="signature"/> 

    <xsl:text>*</xsl:text>

  </code>

  <xsl:text> points to a newly allocated array</xsl:text>

  <xsl:choose>

    <xsl:when test="count(@outcount)=1 and @outcount!=''">

      <xsl:text> of size </xsl:text>

      <code>

        <xsl:text>*</xsl:text>

        <xsl:value-of select="@outcount"/>

      </code>

    </xsl:when>

    <xsl:otherwise>

      <xsl:if test="count(@incount)=1 and @incount!=''">

        <xsl:text> of size </xsl:text>

        <code>

          <xsl:value-of select="@incount"/>

        </code>

      </xsl:if>

    </xsl:otherwise>

  </xsl:choose>

  <xsl:text>.  The array should be freed with </xsl:text>

  <a href="#Deallocate"><code>Deallocate</code></a>

  <xsl:text>. </xsl:text>

  <xsl:apply-templates select="nullok" mode="funcdescription"/>

  <xsl:apply-templates select="child::*[position()=1]" mode="returndescription">

    <xsl:with-param name="plural" select="'plural'"/>

  </xsl:apply-templates>

</xsl:template>

<xsl:template match="allocallocbuf" mode="funcdescription">

  <p/>

  <xsl:text>Agent passes a pointer to a </xsl:text>

  <code>

    <xsl:apply-templates select="child::*[position()=1]" mode="signature"/> 

    <xsl:text>**</xsl:text>

  </code>

  <xsl:text>. </xsl:text>

  <xsl:text>On return, the </xsl:text>

  <code>

    <xsl:apply-templates select="child::*[position()=1]" mode="signature"/> 

    <xsl:text>**</xsl:text>

  </code>

  <xsl:text> points to a newly allocated array</xsl:text>

  <xsl:choose>

    <xsl:when test="count(@outcount)=1 and @outcount!=''">

      <xsl:text> of size </xsl:text>

      <code>

        <xsl:text>*</xsl:text>

        <xsl:value-of select="@outcount"/>

      </code>

    </xsl:when>

    <xsl:otherwise>

      <xsl:if test="count(@incount)=1 and @incount!=''">

        <xsl:text> of size </xsl:text>

        <code>

          <xsl:value-of select="@incount"/>

        </code>

      </xsl:if>

    </xsl:otherwise>

  </xsl:choose>

  <xsl:text>, each element of which is also newly allocated.

  The array should be freed with </xsl:text>

  <a href="#Deallocate"><code>Deallocate</code></a>

  <xsl:text>. 

  Each of the elements should be freed with </xsl:text>

  <a href="#Deallocate"><code>Deallocate</code></a>

  <xsl:text>. </xsl:text>

  <xsl:apply-templates select="nullok" mode="funcdescription"/>

  <xsl:apply-templates select="child::*[position()=1]" mode="returndescription">

    <xsl:with-param name="plural" select="'plural'"/>

  </xsl:apply-templates>

</xsl:template>

<xsl:template match="outbuf" mode="funcdescription">

  <p/>

  <xsl:text>Agent passes an array </xsl:text>

  <xsl:if test="count(@incount)=1 and @incount!=''">

    <xsl:text>large enough to hold </xsl:text>

    <code>

      <xsl:value-of select="@incount"/>

    </code>

    <xsl:text> elements </xsl:text>

  </xsl:if>

  <xsl:text>of </xsl:text>

  <code>

    <xsl:apply-templates select="child::*[position()=1]" mode="signature"/> 

  </code>

  <xsl:text>. The incoming values of the elements of the array are ignored. </xsl:text>

  <xsl:text>On return, </xsl:text>

  <xsl:if test="count(@outcount)=1 and @outcount!=''">

    <code>

      <xsl:text>*</xsl:text>

      <xsl:value-of select="@outcount"/>

    </code>

    <xsl:text> of </xsl:text>

  </xsl:if>

  <xsl:text>the elements are set. </xsl:text>

  <xsl:apply-templates select="nullok" mode="funcdescription"/>

  <xsl:apply-templates select="child::*[position()=1]" mode="returndescription">

    <xsl:with-param name="plural" select="'plural'"/>

  </xsl:apply-templates>

</xsl:template>

<xsl:template match="agentbuf" mode="funcdescription">

  <p/>

  <xsl:apply-templates select="nullok" mode="funcdescription"/>

  <xsl:apply-templates select="child::*[position()=1]" mode="returndescription">

    <xsl:with-param name="plural" select="'plural'"/>

  </xsl:apply-templates>

</xsl:template>

<xsl:template match="jmethodID|jfieldID|jframeID|jrawMonitorID|jclass|jobject|jvalue|jthreadGroup|enum|jint|jchar|jlong|jfloat|jdouble|jlocation|jboolean|char|uchar|size_t|void|varargs|struct" mode="funcdescription">

</xsl:template>

<xsl:template match="jthread" mode="funcdescription">

  <xsl:if test="count(@null)!=0">

    If

    <code>

      <xsl:value-of select="../@id"/>

    </code>

    is

    <code>NULL</code>, the current thread is used.

  </xsl:if>

</xsl:template>

<xsl:template match="jmethodID|jfieldID|jframeID|jrawMonitorID|enum|jint|jchar|jlong|jfloat|jdouble|jlocation|jboolean|char|uchar|size_t|void|varargs" mode="returndescription">

</xsl:template>

<xsl:template match="struct" mode="returndescription">

  <xsl:param name="plural"/>

  <xsl:variable name="structname" select="."/>

  <xsl:for-each select="//typedef[@id=$structname]|//uniontypedef[@id=$structname]">

    <xsl:for-each select="field">

      <xsl:apply-templates select="child::*[position()=1]" mode="fieldreturndescription">

        <xsl:with-param name="plural" select="$plural"/>

      </xsl:apply-templates>

    </xsl:for-each>

  </xsl:for-each>

</xsl:template>

<xsl:template match="jclass|jthread|jobject|jvalue|jthreadGroup" mode="returndescription">

  <xsl:param name="plural"/>

  <xsl:text>The object</xsl:text>

  <xsl:if test="$plural='plural'">

    <xsl:text>s</xsl:text>

  </xsl:if>

  <xsl:text> returned by </xsl:text>

  <code>

    <xsl:value-of select="../../@id"/>

  </code>

  <xsl:choose>    

    <xsl:when test="$plural='plural'">

      <xsl:text> are JNI local references and must be </xsl:text>

    </xsl:when>

    <xsl:otherwise>

      <xsl:text> is a JNI local reference and must be </xsl:text>

    </xsl:otherwise>

  </xsl:choose>

  <a href="#refs">managed</a>.

</xsl:template>

<xsl:template match="outptr|inptr|inbuf|agentbuf|allocbuf|allocallocbuf" mode="fieldreturndescription">

  <xsl:variable name="field" select="ancestor::field"/>

  <xsl:message terminate="yes">

    outptr, allocallocbuf, outbuf, vmbuf, allocbuf, inptr, inbuf or agentbuf as type of returned field:

    <xsl:value-of select="$field/@id"/> of <xsl:value-of select="$field/../@id"/>

  </xsl:message>

</xsl:template>

<xsl:template match="outbuf" mode="fieldreturndescription">

  <!-- hand document this special case.

  -->

</xsl:template>

<xsl:template match="struct" mode="fieldreturndescription">

  <xsl:param name="plural"/>

  <xsl:variable name="structname" select="."/>

  <xsl:for-each select="//typedef[@id=$structname]|//uniontypedef[@id=$structname]">

    <xsl:for-each select="field">

      <xsl:apply-templates select="child::*[position()=1]" mode="fieldreturndescription">

        <xsl:with-param name="plural" select="$plural"/>

      </xsl:apply-templates>

    </xsl:for-each>

  </xsl:for-each>

</xsl:template>

<xsl:template match="allocfieldbuf" mode="fieldreturndescription">

  <xsl:param name="plural"/>

  <xsl:variable name="field" select="ancestor::field"/>

  <xsl:text>The pointer</xsl:text>

  <xsl:if test="$plural='plural'">

    <xsl:text>s</xsl:text>

  </xsl:if>

  <xsl:text> returned in the field </xsl:text>

  <code>

    <xsl:value-of select="$field/@id"/>

  </code>

  <xsl:text> of </xsl:text>

  <code>

    <xsl:value-of select="$field/../@id"/>

  </code>

  <xsl:choose>    

    <xsl:when test="$plural='plural'">

      <xsl:text> are newly allocated arrays. The arrays</xsl:text>

    </xsl:when>

    <xsl:otherwise>

      <xsl:text> is a newly allocated array. The array</xsl:text>

    </xsl:otherwise>

  </xsl:choose>

  <xsl:text> should be freed with </xsl:text>

  <a href="#Deallocate"><code>Deallocate</code></a>

  <xsl:text>. </xsl:text>

  <xsl:apply-templates select="child::*[position()=1]" mode="fieldreturndescription">

    <xsl:with-param name="plural" select="'plural'"/>

  </xsl:apply-templates>

</xsl:template>

<xsl:template match="ptrtype|vmbuf|jmethodID|jfieldID|jframeID|jrawMonitorID|enum|jint|jchar|jlong|jfloat|jdouble|jlocation|jboolean|char|uchar|size_t|void" mode="fieldreturndescription">

</xsl:template>

<xsl:template match="jclass|jthread|jobject|jvalue|jthreadGroup" mode="fieldreturndescription">

  <xsl:param name="plural"/>

  <xsl:variable name="field" select="ancestor::field"/>

  <xsl:text>The object</xsl:text>

  <xsl:if test="$plural='plural'">

    <xsl:text>s</xsl:text>

  </xsl:if>

  <xsl:text> returned in the field </xsl:text>

  <code>

    <xsl:value-of select="$field/@id"/>

  </code>

  <xsl:text> of </xsl:text>

  <code>

    <xsl:value-of select="$field/../@id"/>

  </code>

  <xsl:choose>    

    <xsl:when test="$plural='plural'">

      <xsl:text> are JNI local references and must be </xsl:text>

    </xsl:when>

    <xsl:otherwise>

      <xsl:text> is a JNI local reference and must be </xsl:text>

    </xsl:otherwise>

  </xsl:choose>

  <a href="#refs">managed</a>.

</xsl:template>

<xsl:template match="nullok" mode="signature">

</xsl:template>

<xsl:template match="jmethodID|jfieldID|jrawMonitorID|jclass|jthread|jobject|jvalue|jthreadGroup|jint|jchar|jlong|jfloat|jdouble|jlocation|jboolean|char|size_t|void" mode="signature">

  <xsl:value-of select="name()"/>

</xsl:template>

<xsl:template match="jframeID" mode="signature">

  <xsl:text>jint</xsl:text>

</xsl:template>

<xsl:template match="uchar" mode="signature">

  <xsl:text>unsigned char</xsl:text>

</xsl:template>

<xsl:template match="enum|struct" mode="signature">

  <xsl:value-of select="."/>

</xsl:template>

<xsl:template match="varargs" mode="signature">

</xsl:template>

<xsl:template match="outptr|outbuf|allocfieldbuf" mode="signature">

  <xsl:apply-templates select="child::*[position()=1]" mode="signature"/>

  <xsl:text>*</xsl:text>

</xsl:template>

<xsl:template match="ptrtype" mode="signature">

  <xsl:apply-templates select="child::*[position()=1]" mode="signature"/>

</xsl:template>

<xsl:template match="inptr|inbuf|vmbuf" mode="signature">

  <xsl:text>const </xsl:text>

  <xsl:apply-templates select="child::*[position()=1]" mode="signature"/>

  <xsl:text>*</xsl:text>

</xsl:template>

<xsl:template match="allocbuf|agentbuf" mode="signature">

  <xsl:apply-templates select="child::*[position()=1]" mode="signature"/>

  <xsl:text>**</xsl:text>

</xsl:template>

<xsl:template match="allocallocbuf" mode="signature">

  <xsl:apply-templates select="child::*[position()=1]" mode="signature"/>

  <xsl:text>***</xsl:text>

</xsl:template>

<xsl:template match="nullok" mode="link">

</xsl:template>

<xsl:template match="jmethodID|jfieldID|jrawMonitorID|jclass|jthread|jobject|jvalue|jint|jchar|jlong|jfloat|jdouble|jlocation|jboolean|jthreadGroup" mode="link">

  <a>

    <xsl:attribute name="href">

      <xsl:text>#</xsl:text><xsl:value-of select="name()"/>

    </xsl:attribute>

    <xsl:value-of select="name()"/>

  </a>

</xsl:template>

<xsl:template match="jframeID" mode="link">

  <a>

    <xsl:attribute name="href">

      <xsl:text>#jint</xsl:text>

    </xsl:attribute>

    <xsl:text>jint</xsl:text>

  </a>

</xsl:template>